ControlGetFocus

如果有，则获取目标窗口中含输入焦点的控件。

ControlGetFocus, OutputVar [, WinTitle, WinText, ExcludeTitle, ExcludeText]

参数

OutputVar

用来保存控件标识符的变量名, 控件标识符由控件的类名以及在父窗口中的序列编号组成, 例如 Button12.

WinTitle

窗口标题或识别目标窗口的其他条件。请参阅 WinTitle。

WinText

如果使用此参数, 那么它必须是目标窗口中单个文本元素的子字符串 (和内置的 Window Spy 工具显示的一样). 当 DetectHiddenText 的设置为 ON 时, 那么会检测到隐藏文本元素.

ExcludeTitle

标题中含有此参数值的窗口将被排除.

ExcludeText

文本中含有此参数值的窗口将被排除.

ErrorLevel

[v1.1.04+] 此命令失败时会抛出异常. 想了解更多信息, 请参阅 运行时错误.

如果成功获取含输入焦点的控件, 则 ErrorLevel 被置为 0. 否则 (例如目标窗口不存在或它所有的控件都不含输入焦点) 被置为 1.

备注

此命令获取的控件是含键盘焦点的那个, 即在用户输入时会接收到键击的那个.

目标窗口必须是活动的, 才能含有焦点控件. 如果窗口不是活动的, 则 OutputVar 被置为空.

如果以很高的频率 (即每 500 ms 或更快) 重复执行 ControlGetFocus, 那么可能会干扰用户双击鼠标. 一种解决方法是通过 DllCall 调用操作系统的 GetGUIThreadInfo(). 例如：

; 此脚本获取活动窗口焦点控件的 ahk_id（HWND）。
GuiThreadInfoSize = 48
VarSetCapacity(GuiThreadInfo, GuiThreadInfoSize)
NumPut(GuiThreadInfoSize, GuiThreadInfo, 0)
if not DllCall("GetGUIThreadInfo", uint, 0, str, GuiThreadInfo)
{
    MsgBox GetGUIThreadInfo() indicated a failure.
    return
}
FocusedHWND := NumGet(GuiThreadInfo, 12)  ; 从结构中获取 hwndFocus 字段.
MsgBox % "The focused control's ahk_id (HWND) is " . FocusedHWND
; 此 ID 可以用在所有的控件命令中.  例如:
; ControlGetText, OutputVar,, ahk_id %FocusedHWND%

窗口标题和文本是区分大小写的. 只有在打开 DetectHiddenWindows 设置时，才能检测到隐藏窗口。

相关

ControlFocus, ControlMove, ControlClick, ControlGetText, ControlSetText, ControlSend

示例

ControlGetFocus, OutputVar, Untitled - Notepad
if ErrorLevel
    MsgBox, The target window doesn't exist or none of its controls has input focus.
else
    MsgBox, Control with focus = %OutputVar%