ComObjFlags() [v1.0.96.00+]

获取或改变控制 COM 包装器对象行为的标志。

Flags := ComObjFlags(ComObject [, NewFlags, Mask])

参数

ComObject

COM 对象包装器.

NewFlags

Mask 标识的或要添加或移除的新标志值.

Mask

需要改变的标志位掩码.

Flags

ComObject 的所有标志 (如果指定了 NewFlags, 则为应用后的新标志).

Flags

F_OWNVALUE
1
当前仅对 SafeArray 有效. 如果设置了此标志, 则当包装器对象释放时销毁 SafeArray. 由于 SafeArray 没有引用计数结构, 所以当含有此标志的 SafeArray 被赋值到另一个 SafeArray 的元素时, 会创建一个独立的副本.

一般说明

如果省略 Mask, 则在 NewFlags 指定需要添加 (为正数时) 或移除 (为负数时) 的标志. 例如, ComObjFlags(obj, -1) 会移除 F_OWNVALUE 标志. 不要在 Mask 中使用 0 或 1 外的其他值, 其他所有位保留供将来使用.

相关

ComObjActive, ComObjArray

示例

; 示例: 检查是否存在 F_OWNVALUE 标志.

arr := ComObjArray(0xC, 1)
if ComObjFlags(arr) & 1
    MsgBox arr will be automatically destroyed.
else
    MsgBox arr will not be automatically destroyed.
; 示例: 改变内嵌在其他数组中的数组的行为.

arr1 := ComObjArray(0xC, 3)
arr2 := ComObjArray(0xC, 1)
arr2[0] := "original value"
arr1[0] := arr2         ; 赋值隐式副本.
ComObjFlags(arr2, -1)   ; 移除 F_OWNVALUE.
arr1[1] := arr2         ; 赋值为原始数组.
arr1[2] := arr2.Clone() ; 赋值显式副本.
arr2[0] := "new value"
for arr in arr1
    MsgBox % arr[0]

arr1 := ""
; 由于 arr2 == arr1[1], 所以后面这句无效, 它已经被销毁了: 
;  arr2[0] := "foo"