TrayTip

在托盘图标附近创建气球提示窗口。

TrayTip [, Title, Text, Seconds, Options]

参数

标题

如果省略所有参数, 则移除任何当前显示的托盘提示窗口.

否则, 此参数为窗口标题, 可以长达 73 个字符 (超出此长度的字符不会显示出来).

如果 Title 为空, 则会移除气球窗口中的标题行, 这会让它垂直高度变短.

文本

如果此参数省略或为空, 则移除当前显示的任何托盘提示窗口.

否则, 请指定要显示的消息, 它会显示在 Title 的下面. 仅显示 Text 中前 265 个字符. 可以使用回车 (`r) 或换行 (`n) 来创建多行文本. 例如:Line1`nLine2

如果 Text 较长, 可以通过 延续片段 的方法将其分解成较短的几行, 这样可以增加可读性和可维护性.

要窗口显示的近似秒数, 达到这时间后它会被操作系统自动移除. 指定小于 10 或大于 30 的数字时通常会使用最小 (10) 或最大 (30) 的显示时间代替。如果为空或省略, 则一般使用最小的时间. 此参数可以为 表达式.

真实的时间可能不同于指定的时间. 微软解释说,“如果用户没有在使用计算机,那么系统不会被这个时间计算为超时前经过的时间。”(技术细节请参阅此处。)因此,要更精确地控制托盘提示显示的时间,请使用 Sleep 命令后面跟着不带参数的 TrayTip,或像下面的示例中演示的那样使用 SetTimer

选项

指定下列数字的其中一个来让小图标显示在 Title 的左边:

1: 信息图标
2: 警告图标
3: 错误图标

如果省略, 则它默认为 0, 此时没有图标. 此参数可以为 表达式.

备注

如果脚本没有托盘图标(使用 #NoTrayIconMenu, tray, NoIcon),则不会显示托盘提示的气球窗口。同样地, 如果下列的 REG_DWORD 值已经存在且被设置为 0, TrayTip 不起作用:

HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced >> EnableBalloonTips

在显示气球提示时操作系统通常会播放声音. 此声音可以通过 Options 参数中加上 16 来禁止(即 16 为无声音无图标,17 为无声音信息图标等等)。

相关提示, 每当用户把鼠标悬停在脚本托盘图标上时会显示工具提示. 此工具提示的内容可以使用这样的方法改变:Menu, Tray, Tip, My New Text

相关

ToolTip, SetTimer, Menu, SplashTextOn, MsgBox, InputBox, FileSelectFile, FileSelectFolder

示例

TrayTip, My Title, Multiline`nText, 20, 17

; 要更精确的控制显示的时间
; 而不使用 Sleep 的方法 (它停止了当前线程):
#Persistent
TrayTip, Timed TrayTip, This will be displayed for 5 seconds.
SetTimer, RemoveTrayTip, 5000
return

RemoveTrayTip:
SetTimer, RemoveTrayTip, Off
TrayTip
return

; 要让托盘提示永久显示, 请使用计时器进行周期性的刷新:
SetTimer, RefreshTrayTip, 1000
Gosub, RefreshTrayTip  ; 调用一次来让它立即开始.
return

RefreshTrayTip:
TrayTip, Refreshed TrayTip, This is a more permanent TrayTip., , 16
return